Decode.vbs

This example demonstrates how to decode packets from VBScript.

See also:

PacketX , Packet , SourceMacAddress , SourceIpAddress , SourcePort

'
'// File:         Decode.vbs
'//
'// Description:  This script demonstrates PacketX protocol decoding
'//
'// Notes:        Run the script from command line using the cscript.exe program
'//
'// Created:      May 10, 2004
'//
'// Copyright (c) 2000-2004 BeeSync Technologies.
'

'// Protocol types
const PktXProtocolTypeEthernet = 1
const PktXProtocolTypeIp       = 2
const PktXProtocolTypeUdp      = 3
const PktXProtocolTypeTcp      = 4

'// Create PacketX instance
Set oPktX = WScript.CreateObject("PktX.PacketX","PacketX_")

'// Display network adapters
For i = 1 To oPktX.Adapters.Count
  If oPktX.Adapters(i).IsGood Then
    WScript.Echo "(" & i & ") " & RTrim(LTrim(oPktX.Adapters(i).Description))
  End If
Next

'// Select network adapter
oPktX.Adapter = Nothing
While oPktX.Adapter Is Nothing
  WScript.StdOut.Write "Choose adapter#"
  On Error Resume Next
    oPktX.Adapter = oPktX.Adapters(RTrim(LTrim(WScript.StdIn.ReadLine)))
  On Error Goto 0
Wend

'// Run 60 secs
oPktX.Start
  WScript.Sleep(60000)
oPktX.Stop

'// Print decoding results
Public Sub PacketX_OnPacket(ByRef oPacket)
  Select Case oPacket.Protocol
    Case PktXProtocolTypeEthernet
      WScript.Echo "MAC:" &vbTab&_
        oPacket.SourceMacAddress &vbTab&"=> "&_
        oPacket.DestMacAddress
    Case PktXProtocolTypeIP   
      WScript.Echo "IP:" &vbTab&_
        oPacket.SourceIpAddress &vbTab&"=> "&_
        oPacket.DestIpAddress
    Case PktXProtocolTypeTCP
      WScript.Echo "TCP:" &vbTab&_
        oPacket.SourceIpAddress &vbTab&"=> "&_
        oPacket.DestIpAddress &vbTab& _
        oPacket.SourcePort &vbTab&"=> "&_
        oPacket.DestPort      
    Case PktXProtocolTypeUDP   
      WScript.Echo "UDP:" &vbTab&_
        oPacket.SourceIpAddress &vbTab&"=> "&_
        oPacket.DestIpAddress &vbTab& _
        oPacket.SourcePort &vbTab&"=> "&_
        oPacket.DestPort          
  End Select  
End Sub

---

Copyright © 2000-2007 beeSync. All rights reserved.